Sintaxis y símbolos de APL - APL syntax and symbols

Este artículo contiene el código fuente de APL . Sin el soporte de renderizado adecuado , es posible que vea signos de interrogación, cuadros u otros símbolos en lugar de los símbolos APL .

El lenguaje de programación APL se distingue por ser simbólico en lugar de léxico : sus primitivas se indican mediante símbolos , no palabras. Estos símbolos se diseñaron originalmente como una notación matemática para describir algoritmos. Los programadores de APL a menudo asignan nombres informales cuando discuten funciones y operadores (por ejemplo, producto para × /), pero las funciones centrales y los operadores proporcionados por el lenguaje se indican mediante símbolos no textuales.

Funciones monádicas y diádicas

La mayoría de los símbolos denotan funciones u operadores . Una función monádica toma como argumento el resultado de evaluar todo a su derecha. (Moderado de la forma habitual entre paréntesis.) Una función diádica tiene otro argumento, el primer elemento de datos a su izquierda. Muchos símbolos denotan funciones tanto monádicas como diádicas, interpretadas según el uso. Por ejemplo, ⌊3.2 da 3, el número entero más grande que no está por encima del argumento, y 3⌊2 da 2, el menor de los dos argumentos.

Funciones y operadores

APL usa el término operador en el sentido de Heaviside como moderador de una función en oposición al uso de algún otro lenguaje de programación del mismo término como algo que opera sobre datos, ref. operador relacional y operadores en general . Otros lenguajes de programación a veces también usan este término de manera intercambiable con función , sin embargo, ambos términos se usan en APL de manera más precisa. Las primeras definiciones de los símbolos APL eran muy específicas sobre cómo se categorizaban los símbolos. Por ejemplo, el operador reduce se indica con una barra inclinada y reduce una matriz a lo largo de un eje interponiendo su función operando . Un ejemplo de reducir :

      ×/2 3 4
24

      2×3×4
24

En el caso anterior, el operador de reducción o barra modera la función de multiplicación . La expresión × / 2 3 4 se evalúa como un resultado escalar (solo 1 elemento) mediante la reducción de una matriz por multiplicación. El caso anterior está simplificado, imagina multiplicar (sumar, restar o dividir) más que unos pocos números juntos. (A partir de un vector, × / devuelve el producto de todos sus elementos).

      1 0 1\45 67
45 0 67

      1 0 1/45 0 67
45 67

Los ejemplos de funciones diádicas anteriores [ejemplos de izquierda y derecha] (usando el mismo símbolo / , ejemplo de la derecha) demuestran cómo los valores booleanos (0 y 1) pueden usarse como argumentos izquierdos para las funciones \ expandir y / replicar para producir resultados exactamente opuestos. En el lado izquierdo, el vector de 2 elementos {45 67} se expande donde ocurren los 0 booleanos para dar como resultado un vector de 3 elementos {45 0 67}; observe cómo APL insertó un 0 en el vector. Por el contrario, ocurre exactamente lo contrario en el lado derecho, donde un vector de 3 elementos se convierte en solo 2 elementos; 0s booleanos eliminan elementos usando la función dyadic / slash . Los símbolos APL también operan en listas (vector) de elementos que utilizan tipos de datos distintos a los numéricos, por ejemplo, un vector de 2 elementos de cadenas de caracteres {"Apples" "Oranges"} podría sustituirse por el vector numérico {45 67} anterior.

Reglas de sintaxis

En APL no existe una jerarquía de precedencia para funciones u operadores. APL no sigue la precedencia de operador habitual de otros lenguajes de programación; por ejemplo, ×no vincula sus operandos más "estrechamente" que +. En lugar de la precedencia del operador, APL define una noción de alcance .

El alcance de una función determina sus argumentos . Las funciones tienen un alcance derecho largo : es decir, toman como argumentos correctos todo lo que está a su derecha. Una función diádica tiene un alcance izquierdo corto : toma como argumentos de la izquierda el primer dato a su izquierda. Por ejemplo, (la columna más a la izquierda a continuación es el código de programa real de una sesión de usuario de APL , sangrado = entrada real del usuario , sin sangría = resultado devuelto por el intérprete de APL ):

      1 ÷ 2 ⌊ 3 × 4 - 5
¯0.3333333333
      1 ÷ 2 ⌊ 3 × ¯1
¯0.3333333333
      1 ÷ 2 ⌊ ¯3
¯0.3333333333
      1 ÷ ¯3
¯0.3333333333

Un operador puede tener operandos de función o datos y evaluar una función diádica o monádica. Los operadores tienen un largo alcance izquierdo. Un operador toma como su operando izquierdo la función más larga a su izquierda. Por ejemplo:

     ∘.=/⍳¨3 3
 1 0 0
 0 1 0
 0 0 1

El operando izquierdo para el operador over-each¨ es la función índice.. La función derivada ⍳¨ se usa monádicamente y toma como su operando derecho el vector 3 3. El alcance izquierdo de cada uno es terminado por el operador de reducción , denotado por la barra diagonal . Su operando izquierdo es la expresión de función a su izquierda: el producto externo de la función igual . El resultado de ∘. = / Es una función monádica. Con el alcance derecho largo habitual de una función, toma como argumento derecho el resultado de ⍳¨3 3. Así

     (⍳3)(⍳3)
1 2 3  1 2 3
     (⍳3)∘.=⍳3
1 0 0
0 1 0
0 0 1
     ⍳¨3 3
1 2 3  1 2 3
     ∘.=/⍳¨3 3
 1 0 0
 0 1 0
 0 0 1

      im ← ∘.=⍨∘⍳
      im 3
 1 0 0
 0 1 0
 0 0 1

      Letters←"ABCDE"
      Letters
ABCDE
      ⍴Letters
5
      FindIt←"CABS"
      FindIt
CABS
      ⍴FindIt
4

      Letters ⍳ FindIt
3 1 2 6

Funciones monádicas

Funciones diádicas

A=1: sin(B)    A=5: sinh(B)
A=2: cos(B)    A=6: cosh(B)
A=3: tan(B)    A=7: tanh(B)

Operadores e indicador de ejes

Notas: Los operadores de reducción y exploración esperan una función diádica a su izquierda, formando una función compuesta monádica aplicada al vector de su derecha.

El operador de producto "." espera una función diádica tanto a su izquierda como a su derecha, formando una función compuesta diádica aplicada a los vectores de su izquierda y derecha. Si la función a la izquierda del punto es "∘" (que significa nulo), entonces la función compuesta es un producto externo; de lo contrario, es un producto interno. Un producto interno destinado a la multiplicación de matrices convencional usa las funciones + y ×, reemplazándolas con otras funciones diádicas puede resultar en operaciones alternativas útiles.

Algunas funciones pueden ir seguidas de un indicador de eje entre corchetes (cuadrados), es decir, aparece entre una función y una matriz y no debe confundirse con subíndices de matriz escritos después de una matriz. Por ejemplo, dada la función ⌽ (inversión) y una matriz bidimensional, la función opera por defecto a lo largo del último eje, pero esto se puede cambiar usando un indicador de eje:

        A←4 3⍴⍳12
        A
 1  2  3
 4  5  6
 7  8  9
10 11 12
        ⌽A
 3  2  1
 6  5  4
 9  8  7
12 11 10
        ⌽[1]A
10 11 12
 7  8  9
 4  5  6
 1  2  3
        ⊖⌽A
12 11 10
 9  8  7
 6  5  4
 3  2  1
        ⍉A
1 4 7 10
2 5 8 11
3 6 9 12

Como caso particular, si la función "," de catenados diádicos va seguida de un indicador de eje (o un modificador de eje a un símbolo / función), se puede utilizar para laminar (interponer) dos matrices dependiendo de si el indicador de eje es menor que o mayor que el origen del índice (origen del índice = 1 en la ilustración siguiente):

        B←1 2 3 4
        C←5 6 7 8
        B,C
1 2 3 4 5 6 7 8
        B,[0.5]C
1 2 3 4
5 6 7 8
        B,[1.5]C
1 5
2 6
3 7
4 8

Matrices anidadas

Las matrices son estructuras que tienen elementos agrupados linealmente como vectores o en forma de tabla como matrices , y dimensiones más altas (3D o al cubo, 4D o al cubo a lo largo del tiempo , etc.). Las matrices que contienen tanto caracteres como números se denominan matrices mixtas . Las estructuras de matriz que contienen elementos que también son matrices se denominan matrices anidadas .

Creando una matriz anidada

Sesión de usuario con intérprete de APL	Explicación
X←4 5⍴⍳20 X 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 X[2;2] 7 ⎕IO 1 X[1;1] 1	X conjunto = a matriz con 4 filas por 5 columnas, que consta de 20 enteros consecutivos. El elemento X [2; 2] en la fila 2 - la columna 2 actualmente es un número entero = 7 . Origen del índice inicial Valor ⎕IO = 1 . Por tanto, el primer elemento de la matriz X o X [1; 1] = 1 .
X[2;2]←⊂"Text" X[3;4]←⊂(2 2⍴⍳4) X 1 2 3 4 5 6 Text 8 9 10 11 12 13 1 2 15 3 4 16 17 18 19 20	Elemento en X [fila 2; col 2] se cambia (de 7) a un vector anidado "Texto" usando la función enclose ⊂ . Elemento en X [fila 3; col 4], antes entero 14, ahora se convierte en una matriz 2x2 mini encerrada o anidada 4 de 4 enteros consecutivos. Dado que X contiene números , texto y elementos anidados , es una matriz mixta y anidada . Representación visual de la matriz anidada

Control de flujo

Un usuario puede definir funciones personalizadas que, al igual que las variables, se identifican por su nombre en lugar de por un símbolo no textual. El encabezado de la función define si una función personalizada es niladica (sin argumentos), monádica (un argumento a la derecha) o diádica (argumentos a la izquierda y a la derecha), el nombre local del resultado (a la izquierda de la flecha ← asignar ) y si tiene cualquier variable local (cada una separada por punto y coma ';').

 ∇ RESULT←PI
   RESULT←○1
 ∇

 ∇ AREA←CIRCLEAREA RADIUS
   AREA←PI×RADIUS⋆2
 ∇

 ∇ AREA←DEGREES SEGMENTAREA RADIUS ; FRACTION ; CA
   FRACTION←DEGREES÷360
   CA←CIRCLEAREA RADIUS
   AREA←FRACTION×CA
 ∇

Si las funciones con el mismo identificador pero diferente adicción son distintas está definido por la implementación. Si se permite, entonces una función CURVEAREA podría definirse dos veces para reemplazar tanto la CIRCLEAREA monádica como la SEGMENTAREA diádica anterior, con la función monádica o diádica seleccionada por el contexto en el que se hizo referencia.

Las funciones diádicas personalizadas generalmente se pueden aplicar a parámetros con las mismas convenciones que las funciones integradas, es decir, los arreglos deben tener el mismo número de elementos o uno de ellos debe tener un solo elemento extendido. Hay excepciones a esto, por ejemplo, una función para convertir moneda británica pre-decimal a dólares esperaría tomar un parámetro con exactamente tres elementos que representan libras, chelines y peniques.

Dentro de un programa o una función personalizada, el control puede transferirse condicionalmente a una declaración identificada por un número de línea o una etiqueta explícita; si el objetivo es 0 (cero), esto finaliza el programa o vuelve al llamador de una función. La forma más común usa la función de compresión APL, como en la plantilla (condición) / objetivo que tiene el efecto de evaluar la condición en 0 (falso) o 1 (verdadero) y luego usarla para enmascarar el objetivo (si la condición es falso se ignora, si es verdadero se deja solo para que se transfiera el control).

Por lo tanto, la función SEGMENTAREA puede modificarse para abortar (justo debajo), devolviendo cero si los parámetros (DEGREES y RADIUS a continuación) tienen un signo diferente :

∇ AREA←DEGREES SEGMENTAREA RADIUS ; FRACTION ; CA ; SIGN     ⍝ local variables denoted by semicolon(;)
  FRACTION←DEGREES÷360
  CA←CIRCLEAREA RADIUS        ⍝ this APL code statement calls user function CIRCLEAREA, defined up above.
  SIGN←(×DEGREES)≠×RADIUS     ⍝ << APL logic TEST/determine whether DEGREES and RADIUS do NOT (≠ used) have same SIGN 1-yes different(≠), 0-no(same sign)
  AREA←0                      ⍝ default value of AREA set = zero
  →SIGN/0                     ⍝ branching(here, exiting) occurs when SIGN=1 while SIGN=0 does NOT branch to 0.  Branching to 0 exits function.
  AREA←FRACTION×CA
∇

La función anterior SEGMENTAREA funciona como se esperaba si los parámetros son escalares o matrices de un solo elemento , pero no si son matrices de elementos múltiples, ya que la condición termina basándose en un solo elemento de la matriz SIGN; por otro lado, el usuario La función podría modificarse para manejar correctamente los argumentos vectorizados. La operación a veces puede ser impredecible ya que APL define que las computadoras con capacidades de procesamiento de vectores deben paralelizar y pueden reordenar las operaciones de matriz en la medida de lo posible; por lo tanto, pruebe y depure funciones de usuario, particularmente si se usarán con argumentos vectoriales o incluso matriciales. Esto afecta no solo la aplicación explícita de una función personalizada a las matrices, sino también su uso en cualquier lugar donde una función diádica pueda usarse razonablemente, como en la generación de una tabla de resultados:

        90 180 270 ¯90 ∘.SEGMENTAREA 1 ¯2 4
0 0 0
0 0 0
0 0 0
0 0 0

Una forma más concisa y, a veces, mejor, de formular una función es evitar transferencias explícitas de control, en lugar de utilizar expresiones que evalúen correctamente en todas las condiciones o en las esperadas. A veces es correcto dejar que una función falle cuando uno o ambos argumentos de entrada son incorrectos , precisamente para que el usuario sepa que uno o ambos argumentos utilizados eran incorrectos. Lo siguiente es más conciso que la función SEGMENTAREA anterior. Lo siguiente es importante , maneja correctamente los argumentos vectorizados:

 ∇ AREA←DEGREES SEGMENTAREA RADIUS ; FRACTION ; CA ; SIGN
   FRACTION←DEGREES÷360
   CA←CIRCLEAREA RADIUS
   SIGN←(×DEGREES)≠×RADIUS
   AREA←FRACTION×CA×~SIGN  ⍝ this APL statement is more complex, as a one-liner - but it solves vectorized arguments: a tradeoff - complexity vs. branching
 ∇

        90 180 270 ¯90 ∘.SEGMENTAREA 1 ¯2 4
0.785398163 0           12.5663706
1.57079633  0           25.1327412
2.35619449  0           37.6991118
0           ¯3.14159265 0

Evitar las transferencias explícitas de control también llamados ramificación, si no han sido revisados o cuidadosamente controlado - puede promover el uso de una excesiva complejidad forros uno , verdaderamente "mal entendido y expresiones complejas" y una "escritura exclusiva" estilo, que tiene poco hecho a APL querer por influyentes comentaristas como Edsger Dijkstra . Sin embargo, a la inversa, los modismos de APL pueden ser divertidos, educativos y útiles, si se usan con comentarios útiles ⍝ , por ejemplo, incluyendo la fuente y el significado y la función del idioma (s). Aquí hay una lista de modismos APL , una lista de modismos IBM APL2 aquí y una biblioteca de modismos APL finlandesa aquí .

Diverso

La mayoría de las implementaciones de APL admiten una serie de variables y funciones del sistema, generalmente precedidas por el carácter ⎕ (quad) y o ")" ( gancho = cerrar paréntesis). Particularmente importante y ampliamente implementada es la variable ⎕IO ( Origen del índice ), ya que mientras que el IBM APL original basaba sus matrices en 1, algunas variantes más nuevas las basan en cero:

        X←⍳12
        X
1 2 3 4 5 6 7 8 9 10 11 12
        ⎕IO
1
        X[1]
1

        ⎕IO←0
        X[1]
2
        X[0]
1

        ⎕WA
41226371072

        )VARS
X

También hay funciones del sistema disponibles para que los usuarios guarden el espacio de trabajo actual, por ejemplo, ) GUARDAR y finalizar el entorno APL, por ejemplo, ) APAGADO : a veces se denominan comandos o funciones de gancho debido al uso de un paréntesis o gancho derecho al principio. Existe cierta estandarización de estas funciones cuádruples y de gancho.

Fuentes

El plano multilingüe básico Unicode incluye los símbolos APL en el bloque Técnico misceláneo , que, por lo tanto, generalmente se representan con precisión a partir de las fuentes Unicode más grandes instaladas con la mayoría de los sistemas operativos modernos. Estas fuentes rara vez las diseñan tipógrafos familiarizados con los glifos APL. Por lo tanto, aunque son precisos, los glifos pueden parecer desconocidos para los programadores de APL o ser difíciles de distinguir entre sí.

Algunas fuentes Unicode se han diseñado para mostrar APL correctamente: APLX Upright, APL385 Unicode y SimPL.

Antes de Unicode, a los intérpretes APL se les proporcionaban fuentes en las que los caracteres APL se asignaban a posiciones menos utilizadas en los conjuntos de caracteres ASCII, generalmente en los 128 puntos de código superiores. Estas asignaciones (y sus variaciones nacionales) eran a veces exclusivas del intérprete de cada proveedor de APL, lo que hacía que la visualización de programas de APL en la Web, en archivos de texto y manuales, a menudo fuera problemática.

Función de teclado APL2 para mapeo de símbolos

Teclado APL2

Tenga en cuenta la tecla APL de encendido / apagado: la tecla más a la derecha, justo debajo. También tenga en cuenta el teclado tenía unos 55 únicas (68 enumeran por tablas anteriores, incluidos los símbolos comparativos pero varios símbolos aparecen en las dos teclas de símbolos APL tablas monádicos y diádicas) (funciones 55 APL (operadores) se enumeran en 5110 APL de referencia de IBM Manual), por lo tanto con el uso de las teclas alt, shift y ctrl - teóricamente habría permitido un máximo de 59 (teclas) * 4 (con 2 teclas presionadas) * 3 (con tres teclas presionadas, por ejemplo, ctrl-alt-del) o unas 472 combinaciones de teclas máximas diferentes, acercándose al máximo de 512 caracteres EBCDIC (256 caracteres por 2 códigos para cada combinación de teclas). Nuevamente, en teoría, el teclado que se muestra a continuación habría permitido que se ingresaran mediante el teclado aproximadamente 472 símbolos / funciones APL diferentes, utilizados activamente. En la práctica, las primeras versiones solo usaban algo aproximadamente equivalente a 55 símbolos especiales APL (excluyendo letras, números, puntuación, etc. teclas). Por lo tanto, el APL temprano solo usaba aproximadamente el 11% (55/472) del potencial de utilización de un lenguaje simbólico en ese momento, basado en los límites de las teclas del teclado, nuevamente excluyendo números, letras, puntuación, etc. En otro sentido, los símbolos del teclado la utilización fue más cercana al 100%, altamente eficiente, ya que EBCDIC solo permitía 256 caracteres distintos y ASCII solo 128.

Resolver acertijos

APL ha demostrado ser extremadamente útil para resolver acertijos matemáticos, varios de los cuales se describen a continuación.

Triángulo de Pascal

Tome el triángulo de Pascal , que es una matriz triangular de números en los que los que están en los extremos de las filas son 1 y cada uno de los otros números es la suma de los dos números más cercanos en la fila justo encima (el vértice, 1, está en la parte superior). La siguiente es una función APL de una sola línea para representar visualmente el triángulo de Pascal:

      Pascal←{0~¨⍨a⌽⊃⌽∊¨0,¨¨a∘!¨a←⌽⍳⍵}   ⍝ Create one-line user function called Pascal
      Pascal 7                            ⍝ Run function Pascal for seven rows and show the results below:
                     1                       
                 1       2                   
             1       3       3               
          1      4       6       4           
       1     5       10      10      5       
    1     6      15      20      15      6   
 1     7     21      35      35      21     7

Números primos, contra prueba a través de factores

Determine el número de números primos (el número primo es un número natural mayor que 1 que no tiene divisores positivos distintos de 1 y él mismo) hasta cierto número N. A Ken Iverson se le atribuye la siguiente solución APL de una sola línea al problema:

      ⎕CR 'PrimeNumbers'  ⍝ Show APL user-function PrimeNumbers
Primes←PrimeNumbers N     ⍝ Function takes one right arg N (e.g., show prime numbers for 1 ... int N)
Primes←(2=+⌿0=(⍳N)∘.|⍳N)/⍳N  ⍝ The Ken Iverson one-liner
      PrimeNumbers 100    ⍝ Show all prime numbers from 1 to 100
2 3 5 7 11 13 17 19 23 29 31 37 41 43 47 53 59 61 67 71 73 79 83 89 97
      ⍴PrimeNumbers 100
25                       ⍝ There are twenty-five prime numbers in the range up to 100.

Con frecuencia se necesita examinar el inverso o el opuesto de una solución matemática ( factores enteros de un número ): Demuestre para el subconjunto de números enteros del 1 al 15 que no son primos enumerando sus factores de descomposición . ¿Cuáles son sus factores distintos de uno (# divisible por, excepto 1)?

      ⎕CR 'ProveNonPrime'
Z←ProveNonPrime R
⍝Show all factors of an integer R - except 1 and the number itself,
⍝ i.e., prove Non-Prime. String 'prime' is returned for a Prime integer.
Z←(0=(⍳R)|R)/⍳R  ⍝ Determine all factors for integer R, store into Z
Z←(~(Z∊1,R))/Z   ⍝ Delete 1 and the number as factors for the number from Z.
→(0=⍴Z)/ProveNonPrimeIsPrime               ⍝ If result has zero shape, it has no other factors and is therefore prime
Z←R,(⊂" factors(except 1) "),(⊂Z),⎕TCNL  ⍝ Show the number R, its factors(except 1,itself), and a new line char
→0  ⍝ Done with function if non-prime
ProveNonPrimeIsPrime: Z←R,(⊂" prime"),⎕TCNL  ⍝ function branches here if number was prime

      ProveNonPrime ¨⍳15      ⍝ Prove non primes for each(¨) of the integers from 1 through 15 (iota 15)
    1  prime
    2  prime
    3  prime
    4  factors(except 1)   2 
    5  prime
    6  factors(except 1)   2 3 
    7  prime
    8  factors(except 1)   2 4 
    9  factors(except 1)   3 
    10  factors(except 1)   2 5 
    11  prime
    12  factors(except 1)   2 3 4 6 
    13  prime
    14  factors(except 1)   2 7 
    15  factors(except 1)   3 5

secuencia Fibonacci

Genere una secuencia numérica de Fibonacci , donde cada número subsiguiente en la secuencia es la suma de los dos anteriores:

      ⎕CR 'Fibonacci'              ⍝ Display function Fibonacci
FibonacciNum←Fibonacci Nth;IOwas   ⍝ Funct header, funct name=Fibonacci, monadic funct with 1 right hand arg Nth;local var IOwas, and a returned num.
⍝Generate a Fibonacci sequenced number where Nth is the position # of the Fibonacci number in the sequence.  << function description
IOwas←⎕IO ⋄ ⎕IO←0 ⋄ FibonacciNum←↑0 1↓↑+.×/Nth/⊂2 2⍴1 1 1 0 ⋄ ⎕IO←IOwas   ⍝ In order for this function to work correctly ⎕IO must be set to zero.

      Fibonacci¨⍳14    ⍝ This APL statement says: Generate the Fibonacci sequence over each(¨) integer number(iota or ⍳) for the integers 1..14.
0 1 1 2 3 5 8 13 21 34 55 89 144 233   ⍝ Generated sequence, i.e., the Fibonacci sequence of numbers generated by APL's interpreter.

Otras lecturas

• Polivka, Raymond P .; Pakin, Sandra (1975). APL: El lenguaje y su uso . Prentice Hall. ISBN 978-0-13-038885-8.
• Reiter, Clifford A .; Jones, William R. (1990). APL con acento matemático (1 ed.). Taylor y Francis. ISBN 978-0534128647.
• Thompson, Norman D .; Polivka, Raymond P. (2013). APL2 in Depth (Springer Series in Statistics) (rústica) (Reimpresión del original 1ª ed.). Saltador. ISBN 978-0387942131.
• Gilman, Leonard; Rose, Allen J. (1976). APL: An Interactive Approach (rústica) (3ª ed.). ISBN 978-0471093046.

Ver también

• Técnico misceláneo : bloque Unicode que incluye claves APL
• APL (página de códigos) § Disposición del teclado : información más moderna sobre la distribución del teclado APL

Referencias

enlaces externos

• Referencia de caracteres APL: Página 1 , Página 2 , Página 3 , Página 4
• Página de fuentes de la Asociación Británica de APL
• Página de códigos de IBM 293 también conocida como la página de códigos APL en mainframes
• Información general sobre caracteres APL en el wiki de APL
• extendiendo APL y sus operadores de símbolos de teclado.
• Lee, Xah. "Cómo crear un diseño de teclado APL o símbolos matemáticos" . Consultado el 13 de enero de 2015 .

Tutoriales genéricos en línea

• Una introducción práctica a APL 1 y APL 2 por Graeme Donald Robertson
• APL para PC, servidores y tabletas: NARS con todas las funciones, sin restricciones, APL / 2 descargable gratis con matrices anidadas de Sudley Place Software
• Intérprete GNU APL descargable gratuito para APL por Jürgen Sauermann
• Tutoriales de YouTube APL subidos por Jimin Park, 8 videos instructivos de introducción / principiantes.
• Lista de tutoriales compilados de SIGAPL
• Aprenda APL: un tutorial de APL de MicroAPL

Reglas de sintaxis

• El juego de la vida de Conway en APL, en YouTube
• Iverson, Kenneth E. (1983). "Sintaxis y semántica APL" . ACM SIGAPL APL Quote Quote . 13 (3): 223–231. doi : 10.1145 / 800062.801221 . ISBN 978-0897910958.
• Gffer, M. (1989). "Un futuro APL: ejemplos y problemas" . Cuatrimoto de cotizaciones ACM SIGAPL APL . 19 (4): 158-163. doi : 10.1145 / 75144.75166 . ISBN 978-0897913270.